Treeview

Sur ton code, NodeText fait référence à quoi exactement ?

Je t'envoie un exemple (mais c'est une class vb, je ne connais le c#) qui pourrait faciliter la chose peut-être, avec une classe qui hérite de treeview pour pouvoir construire complétement un arbre personnalisé en asp.
J'ai ajouté également une propriété (nommée ici CImage, qui est boolean, et qui détermine si le noeud doit recevoir ou non une image sur la droite).
J'ai fait un test en ajoutant des noeuds enfants sur un clic sur l'imagebutton des noeuds principaux : ça à l'air de marcher correctement.

Code VB :

Imports Microsoft.VisualBasic
Imports System.Web
Imports System.Web.UI
Imports System.Web.UI.WebControls
Imports System.Web.Services.Protocols

Namespace Arbre
    Public Class MonArbre
        Inherits TreeView
        Protected Overrides Function CreateNode() As System.Web.UI.WebControls.TreeNode
            Return New arbrenoeud()
        End Function
    End Class

    Public Class arbrenoeud
        Inherits TreeNode
        Protected Overrides Sub RenderPostText(ByVal writer As HtmlTextWriter)
            If CImage2 = False Then Return
            writer.AddAttribute(HtmlTextWriterAttribute.Type, "image")
            writer.AddAttribute(HtmlTextWriterAttribute.Src, "et1.png")
            writer.AddAttribute("alt", "image2")
            writer.AddAttribute("onclick", "poster(this)")
            writer.RenderBeginTag(HtmlTextWriterTag.Input)
            writer.RenderEndTag()
            MyBase.RenderPostText(writer)
        End Sub
        Private CImage2 As Boolean
        Public Property CImage() As Boolean
            Get
                Return CImage2
            End Get
            Set(ByVal Value As Boolean)
                CImage2 = Value
            End Set
        End Property

        Protected Overrides Function SaveViewState() As Object
            Dim arrState(2) As Object
            arrState(0) = MyBase.SaveViewState()
            arrState(1) = Me.CImage
            Return arrState
        End Function

        Protected Overrides Sub LoadViewState(ByVal savedState As Object)
            If Not savedState Is Nothing Then
                Dim arrState() As Object = savedState
                Me.CImage = CType(arrState(1), Boolean)
                MyBase.LoadViewState(arrState(0))
            End If
        End Sub
    End Class

End Namespace

Dans ma page,

en y ajoutant :
<%@ Register TagPrefix="toto" Namespace="Arbre" %>
je peux écrire en statique, par exemple :

<toto:MonArbre ID="treeview1" runat="server">
    <Nodes>
    <toto:ArbreNoeud Text="Premier Noeud" CImage="true" ImageUrl="et2.png" Value="1">
        <toto:ArbreNoeud Text="Texte1" ImageUrl="et2.png"  Value="Texte1"></toto:ArbreNoeud>
        <toto:ArbreNoeud Text="Texte2" ImageUrl="et2.png" Value="Texte2"></toto:ArbreNoeud>
    </toto:ArbreNoeud>
    <toto:ArbreNoeud Text="Deuxi&#232;me Noeud" CImage="true" ImageUrl="et2.png" Value="2">
        <toto:ArbreNoeud Text="Texte4" ImageUrl="et2.png" Value="Texte4"></toto:ArbreNoeud>
        <toto:ArbreNoeud Text="Texte5" ImageUrl="et2.png" Value="Texte5"></toto:ArbreNoeud>
    </toto:ArbreNoeud>
    </Nodes>
</toto:MonArbre>


GGtry