EVITER QUE LES ERREURS DES USERCONTROLS, ARRETENT LE FONCTIONNEMENT DE LA PAGE

Imports Microsoft.VisualBasic
Imports System.Web

Public MustInherit Class MonUserControl
    Inherits System.Web.UI.UserControl

#Region " Gestion des exceptions dans l'UC "

    ' En faisant ces bidouilles, il y a trés peu de risques qu'un UC fasse planter toutes la page
    ' en tout cas c'est la meilleure facon que j'ai trouvé. Le mieux aurait été de pouvoir arreter
    ' tout fonctionnement de l'UC, mais ca m'a l'air impossible

    Private lastError As Exception = Nothing
    Private PlaceHolderError As PlaceHolder

    Protected NotOverridable Overrides Sub OnLoad(ByVal e As System.EventArgs)
        Try
            If lastError Is Nothing Then
                MyBase.OnLoad(e)
            End If
        Catch ex As Exception
            lastError = ex
            Me.OnError(e)
        End Try
    End Sub

    Protected NotOverridable Overrides Sub OnInit(ByVal e As System.EventArgs)
        Try
            If lastError Is Nothing Then
                MyBase.OnInit(e)
            End If
        Catch ex As Exception
            lastError = ex
            Me.OnError(e)
        End Try
    End Sub

    Protected NotOverridable Overrides Sub OnPreRender(ByVal e As System.EventArgs)
        Try
            If lastError Is Nothing Then
                MyBase.OnPreRender(e)
            End If
        Catch ex As Exception
            lastError = ex
            Me.OnError(e)
        End Try
    End Sub

    Protected NotOverridable Overrides Sub OnError(ByVal e As System.EventArgs)
        ' on log
        ' CSP.Utilities.Logs.WriteLine(TraceLevel.Error, lastError)
        MyBase.OnError(e)
    End Sub

    Protected NotOverridable Overrides Sub Render(ByVal writer As System.Web.UI.HtmlTextWriter)
        Try
            If lastError Is Nothing Then
                MyBase.Render(writer)
            ElseIf PlaceHolderError IsNot Nothing Then
                PlaceHolderError.RenderControl(writer)
            End If
        Catch ex As Exception
            Me.OnError(EventArgs.Empty)
        End Try
    End Sub

    ''' <summary>
    '''  on recupere les éventuelles erreurs provoqués dans le UserControl
    ''' </summary>
    ''' <param name="sender"></param>
    ''' <param name="e"></param>
    ''' <remarks></remarks>
    Private Sub Page_Error(ByVal sender As Object, ByVal e As System.EventArgs) Handles Me.Error
        If PlaceHolderError Is Nothing Then
            PlaceHolderError = New PlaceHolder
        End If
        PlaceHolderError.Controls.Add(New LiteralControl("Une erreur a été détécté dans cet UserControl"))
    End Sub

#End Region


End Class